summaryrefslogtreecommitdiff
path: root/src/mesa/drivers/osmesa/SConscript
blob: 064f3da5da9492fc6dd9ac3584d026942a6b67e0 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Import('*')

env = env.Clone()

env.Prepend(CPPPATH = [
    '#src',
    '#src/mapi',
    '#src/mesa',
    Dir('../../../mapi'), # src/mapi build path for python-generated GL API files/headers
    Dir('../../../mapi/glapi'), # src/mapi/glapi build path
])

env.Prepend(LIBS = [
    mesautil,
    glapi,
    compiler,
    mesa,
    spirv,
    nir,
    glsl,
])

sources = [
    'osmesa.c',
]

if env['platform'] == 'windows':
    env.AppendUnique(CPPDEFINES = [
        '_GDI32_', # prevent wgl* being declared __declspec(dllimport)
        'BUILD_GL32', # declare gl* as __declspec(dllexport) in Mesa headers
    ])
    if not env['gles']:
        # prevent _glapi_* from being declared __declspec(dllimport)
        env.Append(CPPDEFINES = ['_GLAPI_NO_EXPORTS'])

    sources += ['osmesa.def']

osmesa = env.SharedLibrary(
    target ='osmesa',
    source = sources,
)

env.Alias('osmesa', osmesa)