1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
|
# SPDX-License-Identifier: MIT
#
# Copyright (c) 2025, Oracle and/or its affiliates.
#
# Permission is hereby granted, free of charge, to any person obtaining a
# copy of this software and associated documentation files (the "Software"),
# to deal in the Software without restriction, including without limitation
# the rights to use, copy, modify, merge, publish, distribute, sublicense,
# and/or sell copies of the Software, and to permit persons to whom the
# Software is furnished to do so, subject to the following conditions:
#
# The above copyright notice and this permission notice (including the next
# paragraph) shall be included in all copies or substantial portions of the
# Software.
#
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
# THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
# FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
# DEALINGS IN THE SOFTWARE.
#
#
# Version should match the current Randr version. XRRQueryVersion
# returns the version from randr.h, NOT the version we set here. But we
# try to keep these the same. Note that the library has an extra
# digit in the version number to track changes which don't affect the
# protocol, so Xrandr version l.n.m corresponds to protocol version l.n
#
project(
'libXrandr',
'c',
version: '1.5.5',
license: 'HPND-sell-variant',
license_files: 'COPYING',
meson_version: '>= 1.1.0',
)
# Replacement for XORG_DEFAULT_OPTIONS
cc = meson.get_compiler('c')
if cc.has_argument('-fno-strict-aliasing')
add_project_arguments('-fno-strict-aliasing', language: 'c')
endif
# Replacement for XORG_CHECK_MALLOC_ZERO
add_project_arguments('-DMALLOC_0_RETURNS_NULL', language: 'c')
# Check randr configuration, strip extra digits from package version to
# find the required protocol version
libXrandr_version = meson.project_version()
libXrandr_vers_components = libXrandr_version.split('.')
randrext_version = '.'.join(libXrandr_vers_components[0],
libXrandr_vers_components[1])
# Obtain compiler/linker options for dependencies
dep_libx11 = dependency('x11', required: true, version: '>= 1.6')
dep_randrproto = dependency('randrproto', required: true,
version: '>=' + randrext_version)
dep_libxext = dependency('xext', required: true)
dep_xextproto = dependency('xextproto', required: true)
dep_libxrender = dependency('xrender', required: true)
dep_renderproto = dependency('renderproto', required: true)
libXrandr_sources = [
'src/Xrandr.c',
'src/XrrConfig.c',
'src/XrrCrtc.c',
'src/XrrMode.c',
'src/XrrOutput.c',
'src/XrrProperty.c',
'src/XrrScreen.c',
'src/XrrProvider.c',
'src/XrrProviderProperty.c',
'src/XrrMonitor.c'
]
lib = library(
'Xrandr',
libXrandr_sources,
include_directories: 'include/X11/extensions',
dependencies: [dep_randrproto, dep_libxext, dep_xextproto,
dep_libxrender, dep_renderproto, dep_libx11],
version: '2.2.0',
install: true,
)
dep = declare_dependency(
include_directories: 'include',
link_with: lib,
)
meson.override_dependency('xrandr', dep)
install_headers(
'include/X11/extensions/Xrandr.h',
subdir: 'X11/extensions',
)
pkg = import('pkgconfig')
pkg.generate(
lib,
description: 'X RandR Library',
filebase: 'xrandr',
requires: ['xproto', 'randrproto'],
url: 'https://gitlab.freedesktop.org/xorg/lib/libxrandr/'
)
prog_sed = find_program('sed')
libXrandr_manpages = [
'Xrandr',
'XRRQueryExtension',
'XRRQueryVersion',
'XRRGetScreenInfo',
'XRRFreeScreenConfigInfo',
'XRRSetScreenConfig',
'XRRSetScreenConfigAndRate',
'XRRConfigRotations',
'XRRConfigTimes',
'XRRConfigSizes',
'XRRConfigRates',
'XRRConfigCurrentConfiguration',
'XRRConfigCurrentRate',
'XRRRootToScreen',
'XRRSelectInput'
]
lib_man_suffix = get_option('lib_man_suffix')
foreach man: libXrandr_manpages
custom_target(
f'@man@.man',
input: f'man/@man@.man',
output: f'@man@.@lib_man_suffix@',
command: [
prog_sed,
'-e', 's/__vendorversion__/"libXrandr @0@" "X Version 11"/'.format(meson.project_version()),
'-e', f's/__libmansuffix__/@lib_man_suffix@/g',
'@INPUT@',
],
capture: true,
install: true,
install_dir: get_option('prefix') / get_option('mandir') / f'man@lib_man_suffix@',
)
endforeach
|
