summaryrefslogtreecommitdiff
path: root/pipewire/meson.build
blob: aada8693cab69f52e448365efa795feed2233a6c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
if get_option('pipewire')
	user_hint = 'If you rather not build this, set "pipewire=false".'

	if not get_option('backend-drm')
		error('Attempting to build the pipewire plugin without the required DRM backend. ' + user_hint)
	endif

	depnames = [
		'libpipewire-0.2', 'libspa-0.1'
	]
	deps_pipewire = [ dep_libweston ]
	foreach depname : depnames
		dep = dependency(depname, required: false)
		if not dep.found()
			error('Pipewire plugin requires @0@ which was not found. '.format(depname) + user_hint)
		endif
		deps_pipewire += dep
	endforeach

	plugin_pipewire = shared_library(
		'pipewire-plugin',
		'pipewire-plugin.c',
		include_directories: include_directories('..', '../shared'),
		dependencies: deps_pipewire,
		name_prefix: '',
		install: true,
		install_dir: dir_module_libweston
	)
	env_modmap += 'pipewire-plugin.so=@0@;'.format(plugin_pipewire.full_path())
endif