summaryrefslogtreecommitdiff
path: root/src/gallium/targets/va/meson.build
blob: 3240c66b648283a904edcd77472cc040db6ae7d4 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
# Copyright © 2017-2018 Intel Corporation

# Permission is hereby granted, free of charge, to any person obtaining a copy
# of this software and associated documentation files (the "Software"), to deal
# in the Software without restriction, including without limitation the rights
# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
# copies of the Software, and to permit persons to whom the Software is
# furnished to do so, subject to the following conditions:

# The above copyright notice and this permission notice shall be included in
# all copies or substantial portions of the Software.

# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
# SOFTWARE.

# TODO: support non-static targets
# Static targets are always enabled in autotools (unless you modify
# configure.ac)

va_link_args = []
va_link_depends = []
va_drivers = []

if with_ld_version_script
  va_link_args += ['-Wl,--version-script', join_paths(meson.current_source_dir(), 'va.sym')]
  va_link_depends += files('va.sym')
endif

libva_gallium = shared_library(
  'gallium_drv_video',
  ['target.c', xmlpool_options_h],
  c_args : c_vis_args,
  cpp_args : cpp_vis_args,
  link_args : [va_link_args, ld_args_gc_sections],
  include_directories : [
    inc_common, inc_util, inc_gallium_winsys, inc_gallium_drivers,
  ],
  link_whole : [libva_st],
  link_with : [
    libgalliumvlwinsys, libgalliumvl, libgallium,
    libpipe_loader_static, libws_null, libwsw, libswdri, libswkmsdri,
  ],
  dependencies : [
    dep_libdrm, dep_thread, driver_r600, driver_radeonsi, driver_nouveau,
    idep_mesautil,
  ],
  link_depends : va_link_depends,
  # Will be deleted during installation, see install_megadrivers.py
  install : true,
  install_dir : va_drivers_path,
  name_suffix : 'so',
)

foreach d : [[with_gallium_r600, 'r600'],
             [with_gallium_radeonsi, 'radeonsi'],
             [with_gallium_nouveau, 'nouveau']]
  if d[0]
    va_drivers += '@0@_drv_video.so'.format(d[1])
  endif
endforeach

meson.add_install_script(
  prog_python.path(),
  join_paths(meson.source_root(), 'bin/install_megadrivers.py'),
  libva_gallium.full_path(),
  va_drivers_path,
  va_drivers,
)