summaryrefslogtreecommitdiff
path: root/src/gallium
diff options
context:
space:
mode:
authorDylan Baker <dylan@pnwbakers.com>2017-10-30 14:32:30 -0700
committerDylan Baker <dylan@pnwbakers.com>2017-12-04 14:36:48 -0800
commit22a817af8a89eb3c762fc3e07b443a3ce37d7416 (patch)
tree4295cd8d4e4abe6731ec27fc17f18ee572b8d32f /src/gallium
parent68076b87474e7959c161f3dad3672c9322a2c96f (diff)
meson: build gallium xvmc state tracker
Signed-off-by: Dylan Baker <dylanx.c.baker@intel.com> Reviewed-by: Eric Engestrom <eric.engestrom@imgtec.com>
Diffstat (limited to 'src/gallium')
-rw-r--r--src/gallium/meson.build7
-rw-r--r--src/gallium/state_trackers/xvmc/meson.build53
-rw-r--r--src/gallium/targets/xvmc/meson.build65
3 files changed, 124 insertions, 1 deletions
diff --git a/src/gallium/meson.build b/src/gallium/meson.build
index 904bf859876..584e6729966 100644
--- a/src/gallium/meson.build
+++ b/src/gallium/meson.build
@@ -122,6 +122,9 @@ endif
if with_gallium_vdpau
subdir('state_trackers/vdpau')
endif
+if with_gallium_xvmc
+ subdir('state_trackers/xvmc')
+endif
# TODO: SWR
# TODO: clover
if with_dri
@@ -140,9 +143,11 @@ endif
if with_gallium_vdpau
subdir('targets/vdpau')
endif
+if with_gallium_xvmc
+ subdir('targets/xvmc')
+endif
# TODO: OMX
# TODO: VA
# TODO: xa
-# TODO: xvmc
# TODO: nine
# TODO: tests
diff --git a/src/gallium/state_trackers/xvmc/meson.build b/src/gallium/state_trackers/xvmc/meson.build
new file mode 100644
index 00000000000..a1022c164b1
--- /dev/null
+++ b/src/gallium/state_trackers/xvmc/meson.build
@@ -0,0 +1,53 @@
+# Copyright © 2017 Intel Corporation
+
+# Permission is hereby granted, free of charge, to any person obtaining a copy
+# of this software and associated documentation files (the "Software"), to deal
+# in the Software without restriction, including without limitation the rights
+# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+# copies of the Software, and to permit persons to whom the Software is
+# furnished to do so, subject to the following conditions:
+
+# The above copyright notice and this permission notice shall be included in
+# all copies or substantial portions of the Software.
+
+# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+# SOFTWARE.
+
+libxvmc_st = static_library(
+ 'xvmc_st',
+ files('attributes.c', 'block.c', 'context.c', 'surface.c', 'subpicture.c'),
+ c_args : [c_vis_args],
+ include_directories : [inc_common],
+ dependencies : [dep_xvmc, dep_x11_xcb, dep_xcb, dep_xcb_dri2, dep_xcb_dri3],
+)
+
+# These tests will not work without a working xvmc configuration.
+if with_tests
+ dep_xvmcw = cc.find_library('XvMCW')
+ dep_real_xvmc = dependency('xvmc')
+ foreach x : ['context', 'surface', 'subpicture', 'blocks', 'rendering']
+ _name = 'xvmc_@0@'.format(x)
+ test(_name, executable(
+ _name,
+ files('tests/test_@0@.c'.format(x), 'tests/testlib.c'),
+ dependencies : [
+ dep_real_xvmc, dep_x11_xcb, dep_xcb, dep_xcb_dri2, dep_xcb_dri3, dep_xvmcw,
+ ],
+ )
+ )
+ endforeach
+
+ test('xbmc_bench', executable(
+ 'xvmc_bench',
+ files('tests/xvmc_bench.c', 'tests/testlib.c'),
+ dependencies : [
+ dep_real_xvmc, dep_x11_xcb, dep_xcb, dep_xcb_dri2, dep_xcb_dri3, dep_xvmcw,
+ ],
+ )
+ )
+endif
diff --git a/src/gallium/targets/xvmc/meson.build b/src/gallium/targets/xvmc/meson.build
new file mode 100644
index 00000000000..76de816efed
--- /dev/null
+++ b/src/gallium/targets/xvmc/meson.build
@@ -0,0 +1,65 @@
+# Copyright © 2017 Intel Corporation
+
+# Permission is hereby granted, free of charge, to any person obtaining a copy
+# of this software and associated documentation files (the "Software"), to deal
+# in the Software without restriction, including without limitation the rights
+# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+# copies of the Software, and to permit persons to whom the Software is
+# furnished to do so, subject to the following conditions:
+
+# The above copyright notice and this permission notice shall be included in
+# all copies or substantial portions of the Software.
+
+# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+# SOFTWARE.
+
+# TODO: support non-static targets
+# Static targets are always enabled in autotools (unless you modify
+# configure.ac)
+
+xvmc_link_args = []
+xvmc_link_depends = []
+xvmc_drivers = []
+
+if with_ld_version_script
+ xvmc_link_args += ['-Wl,--version-script', join_paths(meson.current_source_dir(), 'xvmc.sym')]
+ xvmc_link_depends += files('xvmc.sym')
+endif
+
+libxvmc_gallium = shared_library(
+ 'XvMCgallium',
+ 'target.c',
+ c_args : c_vis_args,
+ cpp_args : cpp_vis_args,
+ link_args : [xvmc_link_args, ld_args_gc_sections],
+ include_directories : [
+ inc_common, inc_util, inc_gallium_winsys, inc_gallium_drivers,
+ ],
+ link_with : [
+ libxvmc_st, libgalliumvlwinsys, libgalliumvl, libgallium, libmesa_util,
+ libpipe_loader_static, libws_null, libwsw,
+ ],
+ dependencies : [
+ dep_xcb, dep_x11_xcb, dep_xcb_dri2, dep_xcb_dri3, dep_libdrm,
+ driver_r600, driver_nouveau,
+ ],
+ link_depends : xvmc_link_depends,
+)
+
+foreach d : [[with_gallium_r600, 'r600'], [with_gallium_nouveau, 'nouveau']]
+ if d[0]
+ xvmc_drivers += 'libXvMC@0@.so'.format(d[1])
+ endif
+endforeach
+
+meson.add_install_script(
+ join_paths(meson.source_root(), 'bin/install_megadrivers.py'),
+ libxvmc_gallium.full_path(),
+ xvmc_drivers_path,
+ xvmc_drivers,
+)