summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorDylan Baker <dylan@pnwbakers.com>2017-10-30 14:04:21 -0700
committerDylan Baker <dylan@pnwbakers.com>2017-12-04 14:36:38 -0800
commit68076b87474e7959c161f3dad3672c9322a2c96f (patch)
tree8ff37583edd7242f593cf0a55e0626174a22f7b5
parent085070a2c8c91c14e5a9f46988989faf19b0a125 (diff)
meson: build gallium vdpau state tracker
Signed-off-by: Dylan Baker <dylanx.c.baker@intel.com> Reviewed-by: Eric Engestrom <eric.engestrom@imgtec.com>
-rw-r--r--meson.build45
-rw-r--r--meson_options.txt13
-rw-r--r--src/gallium/meson.build7
-rw-r--r--src/gallium/state_trackers/vdpau/meson.build32
-rw-r--r--src/gallium/targets/vdpau/meson.build71
5 files changed, 166 insertions, 2 deletions
diff --git a/meson.build b/meson.build
index 0f515ad10b8..eeb2adc0ac8 100644
--- a/meson.build
+++ b/meson.build
@@ -361,6 +361,49 @@ if with_dri or with_gallium
endif
endif
+dep_vdpau = []
+_vdpau = get_option('gallium-vdpau')
+if _vdpau == 'auto'
+ if not ['linux', 'bsd'].contains(host_machine.system())
+ with_gallium_vdpau = false
+ elif not with_platform_x11
+ with_gallium_vdpau = false
+ elif not (with_gallium_r300 or with_gallium_r600 or with_gallium_radeonsi or
+ with_gallium_nouveau)
+ with_gallium_vdpau = false
+ else
+ dep_vdpau = dependency('vdpau', version : '>= 1.1', required : false)
+ with_gallium_vdpau = dep_vdpau.found()
+ endif
+elif _vdpau == 'true'
+ if not ['linux', 'bsd'].contains(host_machine.system())
+ error('VDPAU state tracker can only be build on unix-like OSes.')
+ elif not with_platform_x11
+ error('VDPAU state tracker requires X11 support.')
+ with_gallium_vdpau = false
+ elif not (with_gallium_r300 or with_gallium_r600 or with_gallium_radeonsi or
+ with_gallium_nouveau)
+ error('VDPAU state tracker requires at least one of the following gallium drivers: r300, r600, radeonsi, nouveau.')
+ endif
+ dep_vdpau = dependency('vdpau', version : '>= 1.1')
+ with_gallium_vdpau = true
+else
+ with_gallium_vdpau = false
+endif
+if with_gallium_vdpau
+ dep_vdpau = declare_dependency(
+ compile_args : dep_vdpau.get_pkgconfig_variable('cflags').split()
+ )
+endif
+
+if with_gallium_vdpau
+ pre_args += '-DHAVE_ST_VDPAU'
+endif
+vdpau_drivers_path = get_option('vdpau-libs-path')
+if vdpau_drivers_path == ''
+ vdpau_drivers_path = join_paths(get_option('libdir'), 'vdpau')
+endif
+
gl_pkgconfig_c_flags = []
if with_platform_x11
if with_any_vk or (with_glx == 'dri' and with_dri_platform == 'drm')
@@ -890,7 +933,7 @@ if with_platform_x11
dep_xcb_glx = dependency('xcb-glx', version : '>= 1.8.1')
dep_xxf86vm = dependency('xxf86vm', required : false)
endif
- if with_any_vk or with_glx == 'dri'
+ if with_any_vk or with_glx == 'dri' or with_gallium_vdpau
dep_xcb = dependency('xcb')
dep_x11_xcb = dependency('x11-xcb')
endif
diff --git a/meson_options.txt b/meson_options.txt
index 4d56c2404f6..55dfa4600ce 100644
--- a/meson_options.txt
+++ b/meson_options.txt
@@ -56,6 +56,19 @@ option(
description : 'Enable HUD block/NIC I/O HUD status support',
)
option(
+ 'gallium-vdpau',
+ type : 'combo',
+ value : 'auto',
+ choices : ['auto', 'true', 'false'],
+ description : 'enable gallium vdpau state tracker.',
+)
+option(
+ 'vdpau-libs-path',
+ type : 'string',
+ value : '',
+ description : 'path to put vdpau libraries. defaults to $libdir/vdpau.'
+)
+option(
'vulkan-drivers',
type : 'string',
value : 'auto',
diff --git a/src/gallium/meson.build b/src/gallium/meson.build
index 7ef1ffcdf06..904bf859876 100644
--- a/src/gallium/meson.build
+++ b/src/gallium/meson.build
@@ -119,6 +119,9 @@ if with_gallium_virgl
else
driver_virgl = declare_dependency()
endif
+if with_gallium_vdpau
+ subdir('state_trackers/vdpau')
+endif
# TODO: SWR
# TODO: clover
if with_dri
@@ -134,9 +137,11 @@ if with_glx == 'gallium-xlib'
subdir('state_trackers/glx/xlib')
subdir('targets/libgl-xlib')
endif
+if with_gallium_vdpau
+ subdir('targets/vdpau')
+endif
# TODO: OMX
# TODO: VA
-# TODO: vdpau
# TODO: xa
# TODO: xvmc
# TODO: nine
diff --git a/src/gallium/state_trackers/vdpau/meson.build b/src/gallium/state_trackers/vdpau/meson.build
new file mode 100644
index 00000000000..9678b79ef6c
--- /dev/null
+++ b/src/gallium/state_trackers/vdpau/meson.build
@@ -0,0 +1,32 @@
+# Copyright © 2017 Intel Corproration
+
+# Permission is hereby granted, free of charge, to any person obtaining a copy
+# of this software and associated documentation files (the "Software"), to deal
+# in the Software without restriction, including without limitation the rights
+# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+# copies of the Software, and to permit persons to whom the Software is
+# furnished to do so, subject to the following conditions:
+
+# The above copyright notice and this permission notice shall be included in
+# all copies or substantial portions of the Software.
+
+# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+# SOFTWARE.
+
+libvdpau_st = static_library(
+ 'vdpau_st',
+ files(
+ 'bitmap.c', 'decode.c', 'device.c', 'ftab.c', 'htab.c', 'mixer.c',
+ 'output.c', 'preemption.c', 'presentation.c', 'query.c', 'surface.c',
+ ),
+ c_args : [c_vis_args, '-DVER_MAJOR=1', '-DVER_MINOR=0'],
+ include_directories : [
+ inc_include, inc_src, inc_util, inc_gallium, inc_gallium_aux,
+ ],
+ dependencies : [dep_vdpau, dep_xcb, dep_x11_xcb, dep_xcb_dri2],
+)
diff --git a/src/gallium/targets/vdpau/meson.build b/src/gallium/targets/vdpau/meson.build
new file mode 100644
index 00000000000..67f1469fb0f
--- /dev/null
+++ b/src/gallium/targets/vdpau/meson.build
@@ -0,0 +1,71 @@
+# Copyright © 2017 Intel Corporation
+
+# Permission is hereby granted, free of charge, to any person obtaining a copy
+# of this software and associated documentation files (the "Software"), to deal
+# in the Software without restriction, including without limitation the rights
+# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+# copies of the Software, and to permit persons to whom the Software is
+# furnished to do so, subject to the following conditions:
+
+# The above copyright notice and this permission notice shall be included in
+# all copies or substantial portions of the Software.
+
+# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+# SOFTWARE.
+
+# TODO: support non-static targets
+# Static targets are always enabled in autotools (unless you modify
+# configure.ac)
+
+vdpau_link_args = []
+vdpau_link_depends = []
+vdpau_drivers = []
+
+if with_ld_version_script
+ vdpau_link_args += ['-Wl,--version-script', join_paths(meson.current_source_dir(), 'vdpau.sym')]
+ vdpau_link_depends += files('vdpau.sym')
+endif
+if with_ld_dynamic_list
+ vdpau_link_args += ['-Wl,--dynamic-list', join_paths(meson.current_source_dir(), '../dri-vdpau.dyn')]
+ vdpau_link_depends += files('../dri-vdpau.dyn')
+endif
+
+libvdpau_gallium = shared_library(
+ 'vdpau_gallium',
+ 'target.c',
+ c_args : c_vis_args,
+ cpp_args : cpp_vis_args,
+ link_args : [vdpau_link_args, ld_args_gc_sections],
+ include_directories : [
+ inc_common, inc_util, inc_gallium_winsys, inc_gallium_drivers,
+ ],
+ link_with : [
+ libvdpau_st, libgalliumvlwinsys, libgalliumvl, libgallium, libmesa_util,
+ libpipe_loader_static, libws_null, libwsw,
+ ],
+ dependencies : [
+ dep_thread, dep_xcb, dep_x11_xcb, dep_xcb_dri2, dep_libdrm,
+ driver_r300, driver_r600, driver_radeonsi, driver_nouveau,
+ ],
+ link_depends : vdpau_link_depends,
+)
+foreach d : [[with_gallium_r300, 'r300'],
+ [with_gallium_r600, 'r600'],
+ [with_gallium_radeonsi, 'radeonsi'],
+ [with_gallium_nouveau, 'nouveau']]
+ if d[0]
+ vdpau_drivers += 'libvdpau_@0@.so.1.0.0'.format(d[1])
+ endif
+endforeach
+
+meson.add_install_script(
+ join_paths(meson.source_root(), 'bin/install_megadrivers.py'),
+ libvdpau_gallium.full_path(),
+ vdpau_drivers_path,
+ vdpau_drivers,
+)