summaryrefslogtreecommitdiff
path: root/pyuno/meson.build
blob: 7d22b7cac505cb88aae5db876a6721442c10b1cd (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
pyuno_lib = shared_library('pyuno',
  'source/module/pyuno_runtime.cxx',
  'source/module/pyuno.cxx',
  'source/module/pyuno_struct.cxx',
  'source/module/pyuno_callable.cxx',
  'source/module/pyuno_module.cxx',
  'source/module/pyuno_type.cxx',
  'source/module/pyuno_util.cxx',
  'source/module/pyuno_except.cxx',
  'source/module/pyuno_adapter.cxx',
  'source/module/pyuno_gc.cxx',
  'source/module/pyuno_iterator.cxx',
  udk_fake_h,
  cpp_args: ['-DLO_DLLIMPLEMENTATION_PYUNO',
             '-DLIBO_INTERNAL_ONLY'],
  include_directories: [main_inc, udkh_inc, 'inc'],
  link_with: [
    cppu_lib,
    cppuhelper_lib,
    sal_lib,
    salhelper_lib,
  ],
  dependencies: [python3_dep],
  install: true,
)

pyuno_wrapper_lib = shared_library('pyuno_wrapper',
  'source/module/pyuno_dlopenwrapper.c',
  include_directories: [main_inc],
  dependencies: [python3_dep.partial_dependency(compile_args: true), dl_dep],
  install: true,
)

pythonloader_lib = shared_library('pythonloader',
  'source/loader/pyuno_loader.cxx',
  udk_fake_h,
  cpp_args: ['-DLIBO_INTERNAL_ONLY'],
  include_directories: [main_inc, udkh_inc, 'inc'],
  link_with: [cppu_lib, cppuhelper_lib, pyuno_lib, sal_lib],
  dependencies: [python3_dep],
  install: true,
)

if host_machine.system() == 'windows'
  python_bin = executable('python',
    'zipcore/python.cxx',
    cpp_args: ['-DLIBO_INTERNAL_ONLY'],
    include_directories: [main_inc, 'inc'],
    link_with: [oopathutils_lib],
  install: true,
  )
endif