path: root/configure.ac

# Process this file with autoconf to produce a configure script

AC_PREREQ(2.57)
AC_INIT([xf86-video-unichrome],
        0.2.0.0,
        [https://unichrome.sf.net/],
        xf86-video-unichrome)

AC_CONFIG_SRCDIR([Makefile.am])
AM_CONFIG_HEADER([config.h])
AC_CONFIG_AUX_DIR(.)

AM_INIT_AUTOMAKE([dist-bzip2])

AM_MAINTAINER_MODE

# Checks for programs.
AC_DISABLE_STATIC
AC_PROG_LIBTOOL
AC_PROG_CC

# -std=gnu99 is needed because otherwise os.h and commas at the end of enums
# stink up the log. How hard would it have been to avoid those in those
# headers?
# The AC_PROG_CC_C99 macro only came into existence at autoconf 2.60,
# so bluntly force it this way.
if test "x$GCC" = "xyes"; then
        CFLAGS="$CFLAGS -Wall -pedantic -std=gnu99"
fi

AC_ARG_WITH(xorg-module-dir,
            AC_HELP_STRING([--with-xorg-module-dir=DIR],
                           [Default xorg module directory [[default=$libdir/xorg/modules]]]),
            [moduledir="$withval"],
            [moduledir="$libdir/xorg/modules"])

AC_MSG_CHECKING([whether to build wrapper driver])
AC_ARG_WITH(wrapper,
	    AC_HELP_STRING([--with-wrapper],
			   [Enable building of the wrapper driver [[default=yes]]]),
	    ,
	    [with_wrapper=yes])
AC_MSG_RESULT([$with_wrapper])

AM_CONDITIONAL(BUILD_WRAPPER, test x$with_wrapper = xyes)
if test x$with_wrapper = xyes; then
   AC_OUTPUT([wrapper/Makefile])
fi

AC_ARG_ENABLE(dri, AC_HELP_STRING([--disable-dri],
              [Disable DRI support [[default=auto]]]),
              [DRI="$enableval"],
              [DRI=auto])

AC_ARG_ENABLE(have_xvmc, AC_HELP_STRING([--enable-xvmc],
	      [Build XvMC support [[default=auto]]]),
	      [have_xvmc="$enableval"],
	      [have_xvmc=auto])

AC_ARG_ENABLE(drm_driver,
	      AC_HELP_STRING([--disable-drm-driver], [Build DRM driver [[default=auto]]]),
	      [build_drm_driver="$enableval"],
	      [build_drm_driver=auto])

AC_ARG_WITH(linux-modules-dir,
            AC_HELP_STRING([--with-linux-modules-dir=DIR],
                           [Linux kernel modules dir (/lib/modules/<version>). [[default=auto]]]),
            [modules_path="$withval"],
            [modules_path=auto])

AC_ARG_WITH(mesa-dir,
            AC_HELP_STRING([--with-mesa-dir=DIR],
                           [Mesa directory to build DRI driver against. [[default=none]]]),
            [mesa_build_dir="$withval"],
            [mesa_build_dir=""])

# Checks for extensions
XORG_DRIVER_CHECK_EXT(RANDR, randrproto)
XORG_DRIVER_CHECK_EXT(RENDER, renderproto)
XORG_DRIVER_CHECK_EXT(XF86DRI, xextproto x11)
XORG_DRIVER_CHECK_EXT(DPMSExtension, xextproto)
XORG_DRIVER_CHECK_EXT(XSERVER_LIBPCIACCESS, pciaccess)

# Checks for pkg-config packages
PKG_CHECK_MODULES(XORG, [xorg-server xproto fontsproto $REQUIRED_MODULES])

AC_MSG_CHECKING([X SDK headers directory])
sdkdir=$(pkg-config --variable=sdkdir xorg-server)
AC_MSG_RESULT([$sdkdir])

# Checks for libraries.

# Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([inttypes.h])

if test "$DRI" != no; then
        AC_CHECK_FILE([${sdkdir}/dri.h],
                      [have_dri_h="yes"], [have_dri_h="no"])
        AC_CHECK_FILE([${sdkdir}/sarea.h],
                      [have_sarea_h="yes"], [have_sarea_h="no"])
        AC_CHECK_FILE([${sdkdir}/dristruct.h],
                      [have_dristruct_h="yes"], [have_dristruct_h="no"])
	AC_CHECK_HEADERS([GL/gl.h],
		      [have_gl_h="yes"], [have_gl_h="no"])
fi

if test x$DRI = xauto; then
        if test "$have_dri_h" = yes -a \
                "$have_sarea_h" = yes -a \
                "$have_dristruct_h" = yes -a \
		"$have_gl_h" = yes; then
                DRI="yes"
        else
                DRI="no"
        fi
fi
AC_MSG_CHECKING([whether to include DRI support])
AC_MSG_RESULT([$DRI])

AM_CONDITIONAL(DRI, test x$DRI = xyes)
if test "$DRI" = yes; then
        PKG_CHECK_MODULES(DRI, [libdrm xf86driproto])
	AC_DEFINE(DRIVER_DRI,1,[Enable DRI driver support])
fi

AH_VERBATIM([HAVE_DRI],[/* xorg-server.h might not have the same idea. */
#if defined(XF86DRI) && defined(DRIVER_DRI)
#define HAVE_DRI 1
#endif])

# check whether to build Xv.
AC_CHECK_FILE([${sdkdir}/xf86xv.h],
	      [have_xf86xv_h="yes"], [have_xf86xv_h="no"])
AC_CHECK_FILE([${sdkdir}/xf86xvpriv.h],
	      [have_xf86xvpriv_h="yes"], [have_xf86xvpriv_h="no"])
AC_MSG_CHECKING([whether to include XV support])
if test "$have_xf86xv_h" = yes -a \
	"$have_xf86xvpriv_h" = yes; then
	have_xv="yes"
else
	have_xv="no"
fi
AC_MSG_RESULT([$have_xv])
AM_CONDITIONAL(XV, test x$have_xv = xyes)

# Check what parts of XvMC are around.
AC_MSG_CHECKING([XvMC protocol headers directory])
xvmcprotodir=$(pkg-config --variable=includedir xvmc)
AC_MSG_RESULT([$xvmcprotodir])

if test "x$have_xvmc" != xno; then
	AC_CHECK_FILE([${xvmcprotodir}/X11/extensions/XvMC.h],
		      [have_xvmc_h="yes"], [have_xvmc_h="no"])
	AC_CHECK_FILE([${xvmcprotodir}/X11/extensions/vldXvMC.h],
		      [have_vldxvmc_h="yes"], [have_vldxvmc_h="no"])
	AC_CHECK_FILE([${xvmcprotodir}/X11/extensions/XvMClib.h],
		      [have_xvmclib_h="yes"], [have_xvmclib_h="no"])
fi

# check for driver side xvmc support.
AC_MSG_CHECKING([whether to include driver-side XvMC support])
if test "x$have_xv" = xyes -a \
	"x$DRI" = xyes -a \
	"x$have_xvmc" != xno -a \
	"x$have_xvmc_h" = xyes -a \
	"x$have_vldxvmc_h" = xyes; then
	build_xvmc="yes"
else
	build_xvmc="no"
fi
AC_MSG_RESULT([$build_xvmc])
AM_CONDITIONAL(BUILD_XVMC, test "x$build_xvmc" = xyes)
if test "x$build_xvmc" = xyes; then
	AC_DEFINE(BUILD_XVMC, 1, [Build driver side XvMC support])
fi

# check whether we need to build the xvmc library.
AC_MSG_CHECKING([whether to include client-side XvMC support])
if test "x$build_xvmc" = xyes -a \
	"x$have_xvmclib_h" = xyes; then
	build_xvmclib="yes"
else
	build_xvmclib="no"
fi
AC_MSG_RESULT([$build_xvmclib])
AM_CONDITIONAL(BUILD_XVMCLIB, test "x$build_xvmclib" = xyes)
if test "x$build_xvmclib" = xyes; then
	AC_OUTPUT([
		lib/Makefile
		lib/xvmc/Makefile
		])
fi

if test "x$build_xvmclib" = xyes; then
	AC_EGREP_HEADER([dixLookupResourceByType], [${sdkdir}/resource.h],
			[new_lookupresource="yes"], [new_lookupresource="no"])
	AC_MSG_CHECKING([whether LookupIDByType() was replaced by dixLookupResourceByType()])
	AC_MSG_RESULT([$new_lookupresource])
	if test "x$new_lookupresource" = xyes; then
		AC_DEFINE(NEW_LOOKUPRESOURCE, 1,
			  [LookupIDByType() was replaced by dixLookupResourceByType()])
	fi
fi

# vldXvMC.h is broken. It includes XvMClib.h and this leads to a big mess
# in some (possibly broken) installations.
if test "x$build_xvmc" = xyes; then
	# if we have xvmclib.h, then we test this way.
	if test "x$have_xvmclib_h" = xyes; then
		AC_EGREP_HEADER([XvMCQueryExtension], [${xvmcprotodir}/X11/extensions/vldXvMC.h],
				[broken_vldxvmc_h="yes"], [broken_vldxvmc_h="no"])
	else
		AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[#include "vldXvMC.h"]])],
				  [broken_vldxvmc_h="no"], [broken_vldxvmc_h="yes"])
	fi

	AC_MSG_CHECKING([whether vldXvMC.h wrongly includes XvMClib.h])
	AC_MSG_RESULT([$broken_vldxvmc_h])
	if test "x$broken_vldxvmc_h" = xyes; then
		AC_DEFINE(BROKEN_VLDXVMC_H, 1, [vldXvMC.h wrongly includes XvMClib.h])
	fi
fi

# Somewhere along the way the non ANSI C compat code got removed.
AC_CHECK_FILE([${sdkdir}/xf86_ansic.h],
              [AC_DEFINE([HAVE_XF86_ANSIC_H], [1],
		         [xf86 non-ansi C compat code still there?])])

SAVED_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS $XORG_CFLAGS"

# Check wether MonRec has a reducedblanking member.
AC_CHECK_MEMBER([MonRec.reducedblanking],
         [MONREC_HAS_REDUCED=yes], [MONREC_HAS_REDUCED=no],
         [#include "${sdkdir}/xf86.h"])
if test "x$MONREC_HAS_REDUCED" = xyes; then
        AC_DEFINE(MONREC_HAS_REDUCED, 1, [MonRec has member reducedblanking])
fi

CFLAGS="$SAVED_CFLAGS"

# in the xserver 1.7 timeframe, the protocol headers were split up.
AC_MSG_CHECKING([Xext protocol headers directory])
xextprotodir=$(pkg-config --variable=includedir xextproto)
AC_MSG_RESULT([$xextprotodir])

AC_CHECK_FILE([${xextprotodir}/X11/extensions/dpmsconst.h],
	      [have_dpmsconst_h="yes"], [have_dpmsconst_h="no"])
if test "x$have_dpmsconst_h" = xyes; then
	AC_DEFINE(HAVE_DPMSCONST_H, 1, [Proto Headers have dpmsconst.h])
fi

# in the xserver 1.7 timeframe, loader symbol listing vanished.
AC_CHECK_DECL([LoaderRefSymLists],
	      [removed_loader_lists="no"], [removed_loader_lists="yes"],
	      [#include "${sdkdir}/xf86Module.h"])
if test "x$removed_loader_lists" = xyes; then
	AC_DEFINE(REMOVED_LOADER_LISTS, 1, [Build without loader symbol lists.])
fi

# in the xserver 1.7 timeframe, many years after libpciaccess deliberately
# overlooked it, RAC got reinvented.
AC_CHECK_FILE([${sdkdir}/xf86RAC.h],
	      [reinvented_rac="no"], [reinvented_rac="yes"])
AC_MSG_CHECKING([whether RAC got reinvented])
AC_MSG_RESULT([$reinvented_rac])
if test "x$reinvented_rac" = xyes; then
	AC_DEFINE(REINVENTED_RAC, 1, [The RAC infrastructure got reinvented.])
fi

#
# All the magic needed to see whether we can build a drm driver.
#
# for now, we must be linux.
AC_CANONICAL_HOST
if test "x$build_drm_driver" != xno; then
   	AC_MSG_CHECKING([whether we are building on a Linux system])
	case "$host_os" in
		linux*)
			AC_MSG_RESULT([yes])
			;;
		*)
			AC_MSG_RESULT([no])
			build_drm_driver="no"
			;;
	esac
fi

# we must have KBuild.
if test "x$build_drm_driver" != xno; then
	AC_MSG_CHECKING([which linux modules path we are building against])
	if test "x$modules_path" == xauto; then
		modules_path=/lib/modules/`uname -r`
	fi
	AC_MSG_RESULT([$modules_path])

	AC_CHECK_FILE([${modules_path}/build/Makefile],
		      [modules_path_buildable="yes"], [modules_path_buildable="no"])

	AC_MSG_CHECKING([whether we can build against this kernel path])
	if test "x$modules_path_buildable" = xyes; then
		AC_MSG_RESULT([yes])
	else
		AC_MSG_RESULT([no])
		build_drm_driver="no"
	fi
fi

# we also need the drm headers to be present.
if test "x$build_drm_driver" != xno; then
   	AC_CHECK_FILE([${modules_path}/build/drivers/char/drm/drmP.h],
		      [have_drmp_h="yes"], [have_drmp_h="no"])
	if test "x$have_drmp_h" = xno; then
	   	AC_CHECK_FILE([${modules_path}/build/drivers/gpu/drm/drmP.h],
			      [have_drmp_h="yes"], [have_drmp_h="no"])
	fi

	if test "x$have_drmp_h" = xno; then
	   	AC_CHECK_FILE([${modules_path}/source/include/drm/drmP.h],
			      [have_drmp_h="yes"], [have_drmp_h="no"])
	fi

	if test "x$have_drmp_h" = xno; then
		build_drm_driver="no"
	fi
fi

AC_MSG_CHECKING([whether we build the kernel drm driver])
if test "x$build_drm_driver" != xno; then
	build_drm_driver="yes"
fi
AC_MSG_RESULT([$build_drm_driver])
AM_CONDITIONAL(BUILD_DRM, test "x$build_drm_driver" = xyes)
if test "x$build_drm_driver" = xyes; then
	AC_OUTPUT([drm/Makefile])
	DRM_KBUILD_DIR=$modules_path/build
	AC_SUBST([DRM_KBUILD_DIR])
fi

#
# Figure out whether we can build the DRI driver.
#
#
AC_MSG_CHECKING([MESA DRI directory to build against])
if test "x$mesa_build_dir" != x; then
	AC_MSG_RESULT([$mesa_build_dir])
	build_dri_driver="yes"
else
	AC_MSG_RESULT([none])
	build_dri_driver="no"
fi

# check version
if test "x$build_dri_driver" = xyes; then
	AC_CHECK_FILE([${mesa_build_dir}/configs/default],
		      , [build_dri_driver="no"])

	AC_MSG_CHECKING([MESA version])

	if test "x$build_dri_driver" = xyes; then
		mesa_major=`grep "MESA_MAJOR=" ${mesa_build_dir}/configs/default | sed s/MESA_MAJOR=//`
		mesa_minor=`grep "MESA_MINOR=" ${mesa_build_dir}/configs/default | sed s/MESA_MINOR=//`
		mesa_tiny=`grep "MESA_TINY=" ${mesa_build_dir}/configs/default | sed s/MESA_TINY=//`
		if test "x$mesa_major" != x -a \
			"x$mesa_minor" != x -a \
			"x$mesa_tiny" != x; then
			build_dri_driver="yes"
		else
			build_dri_driver="no"
		fi
	fi

	if test "x$build_dri_driver" = xyes; then
		AC_MSG_RESULT([$mesa_major.$mesa_minor.$mesa_tiny])
	else
		AC_MSG_RESULT([failed])
	fi
fi

# due to mesa's unique structure, we need to link statically to libmesa.a
if test "x$build_dri_driver" = xyes; then
	AC_CHECK_FILE([${mesa_build_dir}/src/mesa/libmesa.a],
		      , [build_dri_driver="no"])
fi

AC_MSG_CHECKING([whether we build the MESA DRI driver])
AC_MSG_RESULT([$build_dri_driver])

AM_CONDITIONAL(BUILD_DRI, test "x$build_dri_driver" = xyes)
if test "x$build_dri_driver" = xyes; then
	AC_OUTPUT([dri/Makefile])
	MESA_DIR=$mesa_build_dir
	AC_SUBST([MESA_DIR])
fi

if test "x$build_dri_driver" = xyes; then
	AC_CHECK_FILE([${mesa_build_dir}/src/mesa/drivers/dri/common/dri_metaops.c],
		      [mesa_have_dri_metaops=yes],)
fi
AM_CONDITIONAL(MESA_HAVE_DRI_METAOPS, test "x$mesa_have_dri_metaops" = xyes)

if test "x$build_dri_driver" = xyes; then
	AC_EGREP_HEADER([msaa_samples], [${mesa_build_dir}/src/mesa/drivers/dri/common/utils.h],
			[mesa_have_msaa=yes],)
	if test "x$mesa_have_msaa" = xyes; then
		AC_DEFINE(MESA_HAVE_MSAA, 1, [MESA has MSAA support.])
	fi

	SAVED_CFLAGS="$CFLAGS"

	CFLAGS="-I${mesa_build_dir}/src/mesa/ $DRI_CFLAGS -I${mesa_build_dir}/include/"
	AC_CHECK_MEMBER([struct __DRIextensionRec.name],
			[mesa_dri_screen_extension="yes"], ,
			[#include "GL/gl.h"
			 #include "GL/internal/dri_interface.h"])

	if test "x$mesa_dri_screen_extension" = xyes; then
		AC_DEFINE(MESA_DRI_SCREEN_EXTENSION, 1,
			  [Does MESA have the newer screen Extension API?])

		# only run this test if the previous succeeded.
		AC_CHECK_MEMBER([struct __DRImediaStreamCounterExtensionRec.getDrawableMSC],
				[mesa_dri_reworked_vblank="yes"], ,
				[#include "GL/gl.h"
				 #include "GL/internal/dri_interface.h"])
	fi

	if test "x$mesa_dri_reworked_vblank" = xyes; then
		AC_DEFINE(MESA_DRI_REWORKED_VBLANK, 1,
			  [Was the DRI VBlank infrastructure reworked?])

		# only run this test if the previous succeeded.
		AC_CHECK_MEMBER([struct gl_framebuffer._ColorDrawBufferIndexes],
				[mesa_gl_framebuffer_colordrawbufferindexes="yes"], ,
				[#include "${mesa_build_dir}/src/mesa/main/mtypes.h"])
	fi

	if test "x$mesa_gl_framebuffer_colordrawbufferindexes" = xyes; then
		AC_DEFINE(MESA_GL_FRAMEBUFFER_COLORDRAWBUFFERINDEXES, 1,
			  [Does the gl_framebuffer struct have the _ColorDrawBufferIndexes member.])

		# only run this test if the previous succeeded.
		AC_CHECK_MEMBER([struct __DRIsystemTimeExtensionRec.base],
				[mesa_dri_screen_extension_loader="yes"], ,
				[#include "GL/gl.h"
				 #include "GL/internal/dri_interface.h"])
	fi

	if test "x$mesa_dri_screen_extension_loader" = xyes; then
		AC_DEFINE(MESA_DRI_SCREEN_EXTENSION_LOADER, 1,
 			  [Is the new screen Extension used as a loader interface?])

		# only run this test if the previous succeeded.
		AC_CHECK_DECL([__DRI_LEGACY_VERSION],
			      [mesa_dri2_interface="yes"], ,
			      [#include "GL/gl.h"
				 #include "GL/internal/dri_interface.h"])
	fi

	if test "x$mesa_dri2_interface" = xyes; then
		AC_DEFINE(MESA_DRI2_INTERFACE, 1,
 			  [DRI interface get reworked in the run-up to dri2?])

		# only run this test if the previous succeeded.
		AC_CHECK_MEMBER([struct gl_stencil_attrib._Enabled],
				[mesa_gl_stencil_attrib__enabled=yes], ,
				[#include "${mesa_build_dir}/src/mesa/main/mtypes.h"])
	fi

	if test "x$mesa_gl_stencil_attrib__enabled" = xyes; then
		AC_DEFINE(MESA_GL_STENCIL_ATTRIB__ENABLED, 1,
			  [Does struct gl_stencil_attrib have _Enabled])
	fi

	CFLAGS="$SAVED_CFLAGS"
fi

AC_SUBST([DRI_CFLAGS])
AC_SUBST([XORG_CFLAGS])
AC_SUBST([moduledir])

XORG_MANPAGE_SECTIONS
XORG_RELEASE_VERSION

AC_OUTPUT([
	Makefile
	src/Makefile
	man/Makefile
])